How to Save Windows 10/11 Spotlight Wallpapers

Windows Spotlight brings to you some fantastic images that are worth storing. Unfortunately, at present, Windows 10/11 doesn’t have a GUI option to save these lock screen wallpaper images; this has to be done manually or using a custom app or script. This post tells you how to save Windows Spotlight lock screen images automatically or manually.

How to Save Windows Spotlight Lock Screen Images

The Windows Spotlight images are stored in one of the sub-folders several levels underneath the Local App Data folder, with random file names containing no extension. Here is the folder path

C:\Users\%username%\AppData\Local\Packages\Microsoft.Windows.ContentDeliveryManager_cw5n1h2txyewy\LocalState\Assets

Backup Windows Spotlight images and add .JPG extension

The above location is not meant to be used as a permanent storage area, as the images you see today in that folder wouldn’t be available there forever. If you like to store the photos, copy them to a different folder, under your Pictures folder, or elsewhere.

To preview them after copying them to your Pictures folder, add the .jpg extension to these files. On the folder where you’ve copied the Spotlight images, click the File menu, and select Open command prompt. Typing the following command would add the JPG extension for all files:

REN *  *.jpg

Remove non-wallpaper files such as tile images

The Windows Spotlight store folder also contains images that are not wallpapers, such as logos or tile images of smaller dimensions that need to be filtered out.

Files with a size of less than 400 KB are probably not wallpaper files. However, you can preview them before clearing them out. Hint: Sort the listing by Size column.

Portrait vs. Landscape Images

The Windows Spotlight store folder can contain portrait as well as landscape images.

You may sort the files using the Dimensions column (which you need to add by right-clicking the Column Header in the folder and clicking More..).

Once sorted, you can move the Portrait images to a separate folder, and Landscape ones to another folder.

Backup Spotlight Images Using Script

Here is a VBScript that copies the lock screen wallpaper files from the Assets folder to your Pictures\Spotlight collections folder.

'Copies Spotlight images from Assets folder to "Pictures\Spotlight Collections"
'Picks up only the Landscape images, and having size >250KB.
'Filename: spotlight_collect.vbs © Ramesh Srinivasan - winhelponline.com
'For Windows 10 systems.

Option Explicit
Dim objFSO : Set objFSO = CreateObject("Scripting.FileSystemObject")
Dim WshShell : Set WshShell = WScript.CreateObject("WScript.Shell")
Dim objFolder, oPic
Dim strAssetsFldr, strSpotlightFldr

strAssetsFldr = WshShell.ExpandEnvironmentStrings("%localappdata%") & _
"\Packages\Microsoft.Windows.ContentDeliveryManager_cw5n1h2txyewy\LocalState\Assets"

strSpotlightFldr = WshShell.ExpandEnvironmentStrings("%userprofile%") & _ 
"\Pictures\Spotlight Collection"

If Not objFSO.FolderExists (strSpotlightFldr) Then objFSO.CreateFolder strSpotlightFldr
strSpotlightFldr = strSpotlightFldr & "\"

If objFSO.FolderExists (strAssetsFldr) Then   
   Set objFolder = objFSO.GetFolder(strAssetsFldr)   
   Dim file, iHeight, iWidth
   For Each file In objFolder.Files
      If objFSO.FileExists(strSpotlightFldr & file.Name & ".jpg") <> True _
         And LCase(file.Name) <> "thumbs.db" Then
         If file.Size > 250000 Then
            On Error Resume Next
            Set oPic = LoadPicture(file)
            'Skip pictures that can't be loaded
            If err.number = 0 Then
               iWidth = CInt(round(oPic.width / 26.4583))
               iHeight = CInt(round(oPic.height / 26.4583))
               'Lets copy only Landscape images of size >250KB
               If iHeight < iWidth Then
                  objFSO.CopyFile file, strSpotlightFldr & file.name & ".jpg", False
                  If err.number <> 0 And err.number <> 58 Then
                     WScript.Echo err.number & vbCrLf & err.Description
                  End If
               End If
            End If
            On Error GoTo 0
         End If
      End If
   Next
End If

Script Usage

Copy the above code to Notepad, and save the file with .vbs extension — e.g., spotlight_collect.vbs. Then, double-click to run the script.

You can also place a shortcut of the script in your in the Startup folder or run it as a Scheduled Task at regular intervals (hours) so that you don’t miss a single Windows Spotlight wallpaper.

Alternately, you can use a folder monitoring tool like New File Go and automatically configure the program to trigger the above script when Windows 10 downloads a fresh set of lock screen wallpapers into the Assets folder. Check out the article Get Notified When Windows 10 Brings a New Spotlight Image Every time for more information.

The script does the following:

• Copies only the landscape images by querying the dimensions of each file.
• Copies only files that are >250 KB.
• If a file of the same name exists in the destination, it ignores and copies the next file.
• Adds a .jpg extension to the files copied to the Spotlight collections folder. It doesn’t change the file name so that you don’t end up with duplicates in the folder, especially when you run the script at regular intervals on the same day.

You can run the script at regular intervals using Task Scheduler to copy the new set of Spotlight images downloaded by Windows 10. Once you collect enough wallpapers, you can set the Spotlight Collection folder as the desktop background slideshow for your account. See the article How to Use Windows Spotlight as Desktop Wallpaper Slideshow for more information.

Find where a Windows Spotlight Image was shot

In Windows 10 v1607 and higher, you should be able to see the geographic location of the current Windows Spotlight by hovering your mouse pointer over the “Like what you see?” section. See the post Find the Actual Location Where a Spotlight (Lock Screen) Image was Shot for more information.

Related articles

• How to Find the Current Lock Screen Image File Name and Path?
• Get Notified When Windows 10 Brings a New Spotlight Image Every time.
• Windows Spotlight does not work and is stuck on the same image