How to Find the Current Lock Screen Image File in Windows 10

Windows 10 Spotlight images are stored deep inside the Local Application Data folder, under “Assets” folder as we’ve seen in post How to Backup Windows Spotlight Images in Windows 10.

This post tells you how to find the file name of currently displayed Lock Screen or Windows Spotlight image so that you don’t have to wade through 50+ files in your Assets folder in order to locate a single wallpaper file.

RELATED: How to Find Current Wallpaper (Desktop Background) File in Windows 10

Find the Current Lock Screen Image File

  1. Manually via the registry
  2. Automatically using Windows Script

Find the Current Lock Screen Wallpaper File Name

To find the current lock screen image in Windows 10 v1803 and higher, follow these steps:

  1. Find your user account SID by opening a Command Prompt window and running this command:
    whoami /user

    find account sid using whoami user command

  2. Note down the SID for your account.
  3. In the Registry Editor, go to the following key:
    HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\Creative\
  4. Select the appropriate SID subkey that corresponds to your user account, and double-click to expand it.Under your SID key, there may be more than one subkey underneath. Each subkey refers to a different wallpaper image file.The highest-numbered subkey, which is the last one, stores the file name of the currently used Windows Spotlight wallpaper, in a value named landscapeImage. The other two or more subkeys contain references to recently used wallpaper images.
  5. Select the highest-numbered subkey or the last one listed.

    find current lock screen image creative windows 10 1803 1809 and higher
    (click to view full size)

  6. Double-click landscapeImage and copy the path. That’s your current lock screen wallpaper image file path.
  7. Right-click Start, click  Run and type this:
    explorer /select, [filepath]

    Replace [filepath] with the actual Lock Screen image path you copied from the Registry Editor in step 6, and press ENTER

  8. That command opens the Assets folder with the current Windows 10 Spotlight wallpaper file already selected.lock screen assets current image
  9. You can copy it to your Desktop or Pictures folder, add the .JPG extension and use it.
    lock screen assets current image

For Windows 10 versions earlier than 1803

To find the current lock screen picture’s file and Path in Windows 10 v1803 and earlier, follow these steps:

  1. Start the Registry Editor (regedit.exe) and go to the registry path mentioned above.
    lock screen assets current imageThe value data for LandscapeAssetPath is what you need, if using a computer. PortraitAssetPath image applies to mobile devices. These two values hold the file name of the current Windows Spotlight wallpaper image.
  2. Double-click the LandscapeAssetPath value and copy the data to clipboard.
  3. Right-click Start, click Run and then type this:
    explorer /select, [filepath]

    Of course, replace [filepath] with the actual Lock Screen image path you copied from the Registry Editor, and press ENTER

    That command opens the Assets folder with the current Windows 10 Spotlight wallpaper file already selected. You can copy it to your Desktop or Pictures folder, add the .JPG extension and use it.

  4. Exit the Registry Editor.

Using Script to Find the Current Lock Screen Image File

To find and open the current lock screen (Windows Spotlight image) wallpaper, here is a VBScript. It does the following things:

  • Finds current lock screen image wallpaper file from the registry.
  • Copies current lock screen wallpaper file to Pictures folder and adds a .jpg extension.
  • Previews the wallpaper using your default image viewer.
  • Opens File Explorer and selects the current wallpaper image file.

Usage: Copy the following lines of code to Notepad. Save the file with a .vbs extension. Double-click the file to find the current lock screen image file and preview it automatically.



For versions 1803 and higher

'Find current lock screen wallpaper file in Windows 10
'For Windows 10 build 17134 (v1803) and higher
'Created on 14-May-2019 - (c) Ramesh Srinivasan

Option Explicit
Const HKEY_LOCAL_MACHINE = &H80000002
Dim sWallPaper, oReg, strKeyPath, sCurWP
Dim arrSubKeys, subkey, GetOS, GetBuild

GetVersion()
If InStr(LCase(GetOS), "windows 10") = 0 Then WScript.Quit
If CInt(GetBuild) < 17134 Then WScript.Quit Dim objFSO: Set objFSO = CreateObject("Scripting.FileSystemObject") Dim WshShell : Set WshShell = WScript.CreateObject("WScript.Shell") Dim strUser : strUser = CreateObject("WScript.Network").UserName Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _ "." & "\root\default:StdRegProv") strKeyPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\" & _ "LogonUI\Creative\" + GetSID(strUser) oReg.EnumKey HKEY_LOCAL_MACHINE, strKeyPath, arrSubKeys For Each subkey In arrSubKeys sWallPaper = subkey Next strKeyPath = strKeyPath & "\" & sWallPaper oReg.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath, "landscapeImage", sCurWP If objFSO.FileExists(sCurWP) Then Dim sWPTarget sWPTarget = WshShell.ExpandEnvironmentStrings("%userprofile%") & _ "\Pictures\lockscreen_wallpaper.jpg" objFSO.CopyFile sCurWP, sWPTarget, True WshShell.Run sWPTarget WScript.Sleep 1000 If MsgBox ("Locate wallpaper file in the Assets folder?", vbYesNo, "Find Wallpaper") = 6 Then WshShell.run "explorer.exe" & " /select," & sCurWP End If Else WScript.Echo("The wallpaper image does not exist on the disk!") WScript.Quit End If Function GetSID(UserName) Dim DomainName, Result, WMIUser If InStr(UserName, "\") > 0 Then
      DomainName = Mid(UserName, 1, InStr(UserName, "\") - 1)
      UserName = Mid(UserName, InStr(UserName, "\") + 1)
   Else
      DomainName = CreateObject("WScript.Network").UserDomain
   End If
   On Error Resume Next
   Set WMIUser = GetObject("winmgmts:{impersonationlevel=impersonate}!" _
   		& "/root/cimv2:Win32_UserAccount.Domain='" & DomainName & "'" _
   		& ",Name='" & UserName & "'")
   
   If Err.Number = 0 Then
      Result = WMIUser.SID
   Else
      Result = ""
      WScript.Echo "Can't determine the SID. Quitting.."
      WScript.Quit
   End If
   On Error GoTo 0
   GetSID = Result
End Function

Function GetVersion()
   Dim objWMIService, colOSes, objOS
   Set objWMIService = GetObject("winmgmts:" _
   		& "{impersonationLevel=impersonate}!\\" & "." & "\root\cimv2")
   Set colOSes = objWMIService.ExecQuery("Select * from Win32_OperatingSystem")
   For Each objOS In colOSes
      GetOS =  objOS.Caption
      GetBuild = objOS.BuildNumber
   Next
End Function

For versions 1709 and earlier

'Finds current lock screen wallpaper file, copies it to Pictures folder and previews it.
'Ramesh Srinivasan, Winhelponline.com
'Created on Sep 1, 2016
'For Windows 10 v1709 and earlier
Dim WshShell: Set WshShell = Createobject("Wscript.Shell")
Dim objFSO: Set objFSO = Createobject("Scripting.Filesystemobject")
On error resume next
sCurrLSI = WshShell.RegRead ("HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Lock Screen\Creative\LandscapeAssetPath")
On error goto 0
sDstFL = WshShell.ExpandEnvironmentStrings( "%USERPROFILE%" )
sDstFL = sDstFl & "\Pictures\" & objFSO.GetFileName(sCurrLSI) & ".jpg"
if objFSO.FileExists(sCurrLSI) then
	objFSO.copyfile sCurrLSI, sDstFL
	WshShell.Run sDstFL
else
	Msgbox "Lock Screen image file doesn't exist in the specified location."
end if

Copy the above lines to Notepad, and save it with .vbs extension. Double-click the script to run it. That does all the work for you.

In Windows 10 versions 1803 and higher, the current lock screen wallpaper image is stored in string values (REG_SZ) namely landscapeImage and portraitImage, under the following registry key:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\Creative\<your SID>\<random-key-name>

In Windows 10 version 1709 and earlier, the lock screen image (Windows Spotlight) file name for the currently displayed landscape and portrait assets are stored in the following registry key:

HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Lock Screen\Creative

That’s it! Hope the two methods to find the current Windows 10 lock screen (Windows Spotlight) wallpaper image was useful to you. Let’s know your comments.


One small request: If you liked this post, please share this?

One "tiny" share from you would seriously help a lot with the growth of this blog. Some great suggestions:
  • Pin it!
  • Share it to your favorite blog + Facebook, Reddit
  • Tweet it!
So thank you so much for your support, my reader. It won't take more than 10 seconds of your time. The share buttons are right below. :)

About the author

Ramesh Srinivasan founded Winhelponline.com back in 2005. He is passionate about Microsoft technologies and he has been a Microsoft Most Valuable Professional (MVP) for 10 consecutive years from 2003 to 2012.

7 thoughts on “How to Find the Current Lock Screen Image File in Windows 10”

  1. Apparently, the Lock Registry has moved or no longer exists.
    I see the following:

    Lock Screen
    Feed Manager
    FirstLockAfterSignIn

    The vbs script returns “Lock Screen image file doesn’t exist in the …”

    Reply
  2. i don’t know anything about wallpaper, how to do anything about choosing pictures or any way to make the selections come on my lap-top or put an easy to remeber app to put on my google sherch bar.

    Reply

Leave a Comment