'""""""""""""""""""""""""""""""""""""""
'© Ramesh Srinivasan.
'Launch.vbs - Created on April 06, 2007
'http://www.winhelponline.com/blog
'""""""""""""""""""""""""""""""""""""""

Option Explicit
Dim WshShell, objShell, FSO, objFolder, objFolderItem
Dim strPath, strBaseKey, strExec

Set WshShell = CreateObject("WScript.Shell")
Set objShell = CreateObject("Shell.Application")
Set FSO = CreateObject("Scripting.FileSystemObject")
strPath = FSO.GetParentFolderName (WScript.ScriptFullName)

'Register the RunAs verb for .VBS files
strBaseKey = "HKCU\Software\Classes\"
strExec = "%SystemRoot%\System32\WScript.exe " & _
    Chr(34) & "%1" & Chr(34) & " %*"
WshShell.RegWrite strBaseKey & _
     ".vbs\", "vbsfile", "REG_SZ"
WshShell.RegWrite strBaseKey & _
     "vbsfile\shell\runas\command\", strExec, "REG_EXPAND_SZ"

'Launch the main script (MAIN.VBS) using RunAs
If FSO.FileExists(strPath & "\MAIN.VBS") Then
     Set objFolder = objShell.Namespace(strPath) 
     Set objFolderItem = objFolder.ParseName("MAIN.vbs")
     objFolderItem.InvokeVerb "RunAs"
Else
     MsgBox "Script file MAIN.VBS not found"
End If

'[Cleanup work] Remove the RunAs keys created earlier
WshShell.Regdelete strBaseKey & ".vbs\"
WshShell.Regdelete strBaseKey & "vbsfile\shell\runas\command\"
WshShell.Regdelete strBaseKey & "vbsfile\shell\runas\"
WshShell.Regdelete strBaseKey & "vbsfile\shell\"
WshShell.Regdelete strBaseKey & "vbsfile\"

Set WshShell= Nothing
Set ObjShell= Nothing
Set FSO = Nothing